@Echo off
Rem ---------------------
Rem --- batch menutje ---
:Ask
    set /p CHOICE=VLC to Dreambox - press "s" for stream, "r" for record en "d" for display: 
    IF %CHOICE% == s GOTO stream
    IF %CHOICE% == r GOTO record
    IF %CHOICE% == d GOTO display
goto ask

Rem -----------------------
Rem --- display gekozen ---
:display

Rem ----------------------------------------------------------------------
Rem --- start VLC met de URL waarmee Firefox-Mediaplayerconnectivity   ---
Rem --- als parameter de batch file aanroept (%1)                      ---
Rem --- geen extra vlc parameters nodig                                ---
start C:\progra~1\videolan\VLC0.8.5beta\vlc.exe %1
goto exit

Rem ----------------------
Rem --- record gekozen ---
:record

Rem -------------------------------------------------------------
Rem --- netwerkdisk waarop de .ts file opgeslagen moet worden ---
set MOVIESPATH=t:\

Rem ----------------------------------------------------------------------------------
Rem --- definieer de parameterstring voor VLC                                      ---
Rem --- transcode naar mp2v-formaat (gepikt uit movieplayer.m3u) en schrijf weg    ---
Rem --- als .ts file op netwerkdisk als verkorte-filenaam-uit-parameter.ts         ---
set CMDLIN=:sout=#transcode{vcodec=mp2v,vb=1000,width=704,height=576,acodec=mpga,ab=192,channels=2,audio-sync}:std{access=file,mux=ts,url='%MOVIESPATH%%~n1.ts'}


Rem ------------------------------------------------------------------------------
Rem --- defineer een (te tonen bericht) met de verkorte-filenaam-uit-parameter ---
set message=Recording %~n1

goto execute

Rem ----------------------
Rem --- stream gekozen ---

:stream
Rem ------------------------------------------------------------------------------------
Rem --- definieer de parameterstring voor VLC                                        ---
Rem ---   uitgezonderd de audio-sync parameter identiek aan movieplayer.m3u          ---
Rem ---   transcode naar mp2v-formaat en stuur deze als stream naar de http poort    ---
set CMDLIN=:sout=#transcode{vcodec=mp2v,vb=1000,width=704,height=576,acodec=mpga,ab=192,channels=2,audio-sync}:duplicate{dst=std{access=http,mux=ts,url=:9090/dboxstream}}

Rem ------------------------------------------------------------------------------------
Rem --- Start WGET om de zap:stream:file-button te faken, inclusief dummy.ts file    ---
start C:\Progra~1\GnuWin32\bin\wget --user=root --password=dreambox -O - "http://192.168.1.116/cgi-bin/movieplayer.m3u?command=start&mrl=dummy.ts"

Rem ------------------------------------------------------------------------------
Rem --- defineer een (te tonen bericht) met de verkorte-filenaam-uit-parameter ---
set message=Streaming %~n1

Rem ---------------------------------------------------------------------------------------------
Rem --- start VLC met de benodigd parameters                                                  --- 
Rem ---   de URL waarmee Firefox-Mediaplayerconnectivity als parameter de batch file aanroept ---
:execute
start C:\progra~1\videolan\VLC0.8.5beta\vlc.exe %1 %CMDLIN%

Rem -------------------------------------------------------
Rem --- gooi het gedefinieerde bericht naar de display  ---
echo .
echo %message%
echo .

Rem -----------------------------------------------------------------------
Rem --- Pauzeer de batch file nog even om het bericht nog even te tonen ---
pause 

:exit